Zum Inhalt

Einzelserver: Daten sichern

Das versiondog System bietet die Möglichkeit, die Daten des Serverarchivs manuell oder in regelmäßigen Abständen automatisch über eine Batchdatei zu sichern.

Voraussetzungen

Um eine Datensicherung des Serverarchivs durchzuführen, müssen zwingend folgende Voraussetzungen erfüllt sein:

  • Der Benutzer, der die Datensicherung manuell durchführt, muss über Administratorrechte auf dem Serversystem verfügen.
  • Der Dienst VDog MasterService muss beendet werden, bevor die Daten gesichert werden.
  • Das Datenbanksystem PostgreSQL (Applikation PostgreSQL.exe) wird mit dem VDog MasterService beendet. Zur Sicherheit können Sie dies im Service Control Manager prüfen.

Wenn diese Voraussetzungen nicht erfüllt sind, kann das Serverarchiv zerstört werden und es kann zu Datenverlust kommen.

Warning

Während der Datensicherung steht das System nicht zur Verfügung. Es wird empfohlen, die Datensicherung in Nebenzeiten durchzuführen, beispielsweise in der Nacht oder an Wochenenden.

Möglichkeiten, Speicherplatz zu sparen:

  • Das Verzeichnis VD_TMP_VD des Serverarchivs beinhaltet nur temporäre Dateien. Sichern Sie das Serverarchiv ohne das Verzeichnis VD_TMP_VD.
  • Das Verzeichnis vdServerArchive kann vor dem Sichern komprimiert werden. Zum Komprimieren muss eine entsprechende ZIP-Anwendung installiert sein.

Daten manuell sichern

Warning

Wenn Sie ein Remote-Archiv verwenden, müssen Sie immer sowohl das Remote-Archiv als auch das lokale Serverarchiv sichern.

Lokales Archiv

Kopieren Sie das lokale Verzeichnis vdServerArchive an den gewünschten Speicherort, z. B. auf eine externe Festplatte.

Remote-Archiv

Kopieren Sie das Verzeichnis vdServerArchive der Remote-Freigabe an den gewünschten Speicherort, z. B. auf eine externe Festplatte.

Daten automatisch sichern

Sie können das Verzeichnis vdServerArchive automatisch sichern, indem Sie eine Batchdatei erstellen und diese mit dem Windows Task Scheduler (= der Aufgabenplanung) zu einem bestimmten Zeitpunkt ausführen.

Beispiel: Datei Backup.bat

Info

Um die Batchdatei aus dem Beispiel für Ihr System zu nutzen, passen Sie alle Pfadangaben in der Datei an Ihr System an.

set SERVERARCHIVE="D:\vdServerArchive\*"
rem If no remote archive, set the variable remotearchive to an empty value.
rem set REMOTEARCHIVE=""
set REMOTEARCHIVE="\\storage\share\vdServerArchive\*"
set OUTFILE="D:\vdServerBackup.zip"
set 7ZIP="%PROGRAMFILES(x86)%\7-Zip\7z.exe"

net stop "VDog MasterService"

if NOT "%ERRORLEVEL%"=="0" (
if NOT "%ERRORLEVEL%"=="2" (
echo Could not stop server
exit /B %ERRORLEVEL%
)
)

tasklist /fi "ImageName eq VDog*" /fo csv 2>NUL | find /I "VDog">NUL
if "%ERRORLEVEL%"=="0" (
echo Server processes still running
tasklist /fi "ImageName eq VDog*" /fo csv
exit /B 1
)

tasklist /fi "ImageName eq postgres.exe" /fo csv 2>NUL | find /I "postgres.exe">NUL
if "%ERRORLEVEL%"=="0" (
tasklist /fi "ImageName eq postgres.exe" /fo csv
echo Database processes still running
exit /B 1
)

REM Backup local server archive with 7-zip
"%7ZIP%" u -t7z -r %OUTFILE% %SERVERARCHIVE%
if NOT "%ERRORLEVEL%"=="0" (
echo Could not zip server archive
exit /B %ERRORLEVEL%
)

if "%REMOTEARCHIVE%" == "" GOTO startms
REM Backup remote server archive with 7-zip
"%7ZIP%" u -t7z -r %OUTFILE% %REMOTEARCHIVE%
if NOT "%ERRORLEVEL%"=="0" (
echo Could not zip remote archive
exit /B %ERRORLEVEL%
)

:startms
net start "VDog MasterService"
if NOT "%ERRORLEVEL%"=="0" (
echo Could not start server
exit /B %ERRORLEVEL%
)

echo "success"
pause

Verwandte Themen